《FF14》5.21生產80級配方手法
FF14的5.21版本參與第二次重建伊修加德需要生產職業的大力幫助,其中80級的配方想要三擋需要一定的操作,那麼80級配方巨集改怎麼設定?下面就給大家帶來5.21生產80級配方手法。
5.21生產80級配方手法
5.1的土豪手法13步,5.2的平民手法13步,你怎麼變得這麼菜了 雖然本來就菜
常規手法,穿齊全套430hq即可使用,應該不會有比這屬性還低的滿級工匠了
巨集
/ac "閒靜" <wait.3>
/ac "掌握" <wait.2>
/ac "儉約" <wait.2>
/ac "坯料加工" <wait.3>
/ac "坯料加工" <wait.3>
/ac "改革" <wait.2>
/ac "坯料加工" <wait.3>
/ac "加工" <wait.3>
/ac "闊步" <wait.2>
/ac "比爾格的祝福" <wait.3>
/ac "崇敬" <wait.2>
/ac "坯料製作" <wait.3>
/ac "坯料製作" <wait.3>
/echo Macro #1 complete <se.14>
無掌握手法,CP要求476,需要穿齊430hq後打幾顆CP石頭 80級了你還不清職業任務?
巨集
/ac "閒靜" <wait.3>
/ac "長期儉約" <wait.2>
/ac "坯料加工" <wait.3>
/ac "坯料加工" <wait.3>
/ac "改革" <wait.2>
/ac "坯料加工" <wait.3>
/ac "加工" <wait.3>
/ac "闊步" <wait.2>
/ac "比爾格的祝福" <wait.3>
/ac "精修" <wait.3>
/ac "崇敬" <wait.2>
/ac "坯料製作" <wait.3>
/ac "坯料製作" <wait.3>
/echo Macro #1 complete <se.14>
高配11步短手法,雙圍要求2480/2537(實際上不需要這麼高作業,但5.2還沒2480作業是不是不太合適)
巨集
/ac "閒靜" <wait.3>
/ac "掌握" <wait.2>
/ac "精密製作" <wait.3>
/ac "精密製作" <wait.3>
/ac "精密製作" <wait.3>
/ac "改革" <wait.2>
/ac "精密製作" <wait.3>
/ac "精密製作" <wait.3>
/ac "闊步" <wait.2>
/ac "比爾格的祝福" <wait.3>
/ac "坯料製作" <wait.3>
/echo Macro #1 complete <se.14>
一個更優秀的11步高配手法,雙圍需求2480/2424
巨集
/ac "堅信" <wait.3>
/ac "內靜" <wait.2>
/ac "長期儉約" <wait.2>
/ac "精密製作" <wait.3>
/ac "坯料加工" <wait.3>
/ac "改革" <wait.2>
/ac "坯料加工" <wait.3>
/ac "坯料加工" <wait.3>
/ac "闊步" <wait.2>
/ac "比爾格的祝福" <wait.3>
/ac "坯料製作" <wait.3>
/echo Macro #1 complete <se.14>
更快的10步高配手法,雙圍需求2534/2479,
巨集
/ac "閒靜" <wait.3>
/ac "長期儉約" <wait.2>
/ac "精密製作" <wait.3>
/ac "改革" <wait.2>
/ac "坯料加工" <wait.3>
/ac "坯料加工" <wait.3>
/ac "闊步" <wait.2>
/ac "比爾格的祝福" <wait.3>
/ac "坯料製作" <wait.3>
/ac "坯料製作" <wait.3>
/echo Macro #1 complete <se.14>
相關攻略文章
沙特王儲也是《FF14》玩家 打遊戲還帶“教練”
《ff14》萌新招待解除方法
吉田直樹:未來會增加《FF14》的難度 現在太簡單了
《ff14》手動下載補丁包安裝方法
《ff14》生產職業推薦
《ff14》過期神典石去兌換在哪裡介紹
《ff14》阿馬羅介紹
《ff14》掉幀解決方法介紹
《ff14》尋蹤覓影稱號獲取方法
Xbox宣佈《FF14》公測版今日上線XSX 隨後光速刪除
吉田直樹:不在SE也會玩《FF14》就算去世都會惦念它
獸人控又狂喜了!《FF14》女硌獅族太香 玩家想入坑